Идентификатор [c]$cut_symbols()[/c] в строке 7 вырезает из текста все символы, которые были перечислены через запятую в одноимённом алиасе "cut_symbols" (см. строку 31).

Поэтому при проверке текста ссылка: [c=blue]http://www.sample.org/sample/something.html[/c] выглядит как: [c=red]httpwwwsampleorgsamplesomethinghtml[/c], что не соответствует указанной ссылке в файле исключения.

Я внёс некоторые изменения в код, чтобы при обнаружении в тексте маски [c]*http*[/c] ничего не было вырезано, кроме кодов управления цветом, жирностью, подчёркиванием и т.д.

[indent=0.8,0.5]
Попробуйте использовать это обновление:

on *:TEXT:*:#test:{ 
  if ($nick($chan,$nick,~&@%+)) { return }
  check_bad_words $chan $nick $1-
}

alias -l check_bad_words {
  var %chan $1, %nick $2, %addr $ial(%nick).addr
  var %t $strip($3-), %text $cut_symbols($lower(%t))
  if (*http* iswm %t) var %text %t
  var %i 1 | while (%i <= $lines($bwfile)) {
    var %bw $read($bwfile,nt,%i)
    if (%bw iswm %text) {
      var %e 1 | while (%e <= $lines($exfile)) {
        if ($read($exfile,nt,%e) iswm %text) { break }
        if (%e == $lines($exfile)) {
          if (!$hget($+(kick,%chan),%nick)) {
            kick %chan %nick Warning: use of bad word in message, next is ban!
            hadd $+(-mu,$ktimer) $+(kick,%chan) %nick $true
          }
          else {
            ban $+(-ku,$btimer) %chan %nick 2 Reason: use of bad word in message
            write $blfile %bw $date $time %nick ---> %addr
            hdel $+(kick,%chan) %nick
          }
        }
        inc %e
      }
    }
    inc %i
  }
}

alias -l cut_symbols { return $remove($1-,.,:,;,_,-,~,=,+,@,$,&,!,?,`,',*,^,",<,>,/,|,\,[,],$chr(35),$chr(37),$chr(40),$chr(41),$chr(44),$chr(123),$chr(125)) }

alias -l bwfile { return badwords\badwords.txt }
alias -l exfile { return badwords\exceptions.txt }
alias -l blfile { return badwords\banlog.txt }
alias -l ktimer { return 300 }
alias -l btimer { return 3600 }

Подпись автора

[html]<style>img {vertical-align:middle;}.hnet{color:#FFFFFF;}.hstar{color:#DE0000;}.htext{font-family:Verdana;font-size:13px;color:#6E1E00;}.heading{font-family:Verdana;font-size:13px;font-weight:bold;background-color:#4897E7;}.stitle{font-family:Verdana;font-size:12px;}.dot{color:#808000;}.desc{color:#ADADAD;}a .curl{font-family:Verdana;font-size:13px;color:#3A92CD;}</style><table><tr><td width="20px" height="20px"><img src="http://forumstatic.ru/files/000d/c9/8c/34681.jpg"></td><td><a href="http://forum.epicnet.ru/viewtopic.php?id=234"><span class="heading"> <span class="hstar">★</span> <span class="hnet">EpicNet.Ru</span> <span class="hstar">★</span> </span><span class="htext"> - IRC Чат © 2008</span></a></td></tr><tr><td></td><td><div class="stitle"><span class="dot">•</span> <span class="desc">Вход через вебгейт:</span> <a href="http://irc.epicnet.ru"><span class="curl">http://irc.epicnet.ru</span></a><br><span class="dot">•</span> <span class="desc">Сервер:</span> irc.epicnet.ru <span class="desc">Порты:</span> 6667, 6668 (ssl)<br><div></td></tr></table>[/html]