#anti-pv off
on *:TEXT:*:?:{
  if ($me == %arq_nick_off && !$hget(arq_no,$nick)) {
    if (!$read(%arq_path, w, $nick)) {
      if (!$hget(arq,$nick)) {
        msg $nick (Auto message) I'm offline. Please leave your message here. | .hadd -mz arq $nick %arq_mes_time
        if (!$window(@AutoReplyQuery)) .window -enz @AutoReplyQuery
        .aline -hp @AutoReplyQuery $+([,$time,]) $nick - wrote to you in private in your absence.
      }
      if (%arq_close) .close -m $nick
    }
    else { if ($hget(arq,$nick)) .hdel -sw arq $nick }
  }
}
on *:INPUT:?: if (!$hget(arq_no,$active)) .hadd -m arq_no $active 1
#anti-pv END
---------------------------------------------------
menu menubar,status,channel,query,@AutoReplyQuery {
  Auto-reply-query
  .$iif($group(#anti-pv).status == on, $style(1)) Enabled : arq_enable
  .$iif($group(#anti-pv).status == off, $style(1)) Disabled : arq_disable
  .-
  .$iif(%arq_nick_off, $style(1) Offline nick - %arq_nick_off, Set offline nick)
  ..Edit : %arq_nick_off = $$?="Enter the nick with which the script should work:"
  ..Delete : unset %arq_nick_off
  .$iif($lines(%arq_path) > 0, $style(1) Exclusion nicks = $lines(%arq_path), Exclusion nicks) : arq_exc_nicks
  .-
  .$iif(%arq_con_time && %arq_mes_time, $style(1) Set timers, Set timers)
  ..$iif(%arq_con_time, Connection delay timer = %arq_con_time sec, Connection delay timer) : arq_con_timer
  ..$iif(%arq_mes_time, Repeat message delay timer = %arq_mes_time sec, Repeat message delay timer) : arq_mes_timer
  ..-
  ..Default timers : %arq_con_time = 10 | %arq_mes_time = 3600
  .$iif(%arq_close, $style(1) Close query - Yes, Close query - No) : %arq_close = $$?!="Do you want query windows to close auto?"
  .Reset hash nicks : .hfree -sw arq* | .echo -a All hash entries with nicks have been removed.
}
on *:CONNECT: arq_default | .timerARQ 1 %arq_con_time arq_enable
on *:EXIT: arq_disable
---------------------------------------------------
alias arq_enable { .enable #anti-pv | .window -enz @AutoReplyQuery }
alias arq_disable { .disable #anti-pv | .close -@ @AutoReplyQuery }
alias arq_default { if (!%arq_con_time) %arq_con_time = 10 | if (!%arq_mes_time) %arq_mes_time = 3600 }
alias arq_exc_nicks { %arq_path = scripts\arq_nicks.txt | if (!$exists(%arq_path)) .write %arq_path | .run %arq_path }
alias arq_con_timer { %arq_con_time = $$?="Enter the number of seconds to delay enabling the script on connection:" }
alias arq_mes_timer { %arq_mes_time = $$?="Enter the number of seconds that must elapse before can receive new auto message:" }