;######################################################################
;#  Name: Captcha Channel Security v1.0
;#  Author: Epic (http://epicnet.ru, irc.epicnet.ru:6667 #Code)
;#  Description: The script sets the channel mode (+Dm) to protect against spam/flood bots and requires each 
;#               new visitor and all channel users who do not have "voice" status to enter the correct captcha  
;#               code to obtain the (+v) mode in order to have access to communication on the channel.
;######################################################################

menu channel {
  $+(Captcha Channel Security,$chr(9),$iif(%ccs_work == on,ON,OFF))
  .$iif(%ccs_work == on,$style(1)) ON: %ccs_work = on | ccs_work $chan
  .$iif(%ccs_work == off,$style(1)) OFF: %ccs_work = off | ccs_work $chan
}
alias -l ccs_work {
  if (%ccs_work == on) {
    mode $1 +Dm | .enable #CaptchaChannelSecurity | .timerCCS 0 15 who $1 $+(n,$chr(37),cnf)
    echo -at Captcha Channel Security Script is On! Make 4Sure That everyone is +v
  }
  if (%ccs_work == off) {
    mode $chan -Dm | .disable #CaptchaChannelSecurity | .hfree -sw captcha | .timerCCS off
    echo -at Captcha Channel Security Script is Off!
  }
}

#CaptchaChannelSecurity off
on *:TEXT:*:?:{
  if ($hget(captcha,$nick)) {
    var %hvalue $v1, %chan $gettok(%hvalue,1,32), %answer $gettok(%hvalue,2,32)
    if ($1 == %answer) {
      mode %chan +v $nick | .hdel -sw captcha $nick
      .msg $nick Thank. This is the correct answer. Welcome! You can now chat on the channel $+(,%chan,,.)
    }
  }
}
raw 354:*: if (!$regex($4,[!~&@%+])) captcha_msg $2 $3 | haltdef
raw 352:*: haltdef
raw 301:*: haltdef
raw 315:*: haltdef
alias -l captcha_msg {
  if (!$hget(captcha,$2)) {
    var %captcha $captcha_generator | .hadd $+(-mu,$hash_storage_time) captcha $2 $1 %captcha
    var %t1 ATTENTION: You just tried to join $chan channel $+(,$1,,.)
    var %t2 Since we are attacked by spam/flood Bots, please enter verification code: $+("04,%captcha,") to prove that you're a human.
    var %t3 If you enter the correct answer, you will be allowed to chat on the channel. If you screw up, nothing will happen.
    .msg $2 %t1 %t2 %t3
  }
}
alias -l captcha_generator {
  var %n1 $crand(A,Z,2), %n2 $crand(1,10,2), %n3 $crand(A,Z,3)
  var %n4 $crand(1,10,3), %n5 $crand(A,Z,2), %n6 $crand(1,10,2)
  return $+(%n1,%n2,%n3,%n4,%n5,%n6)
}
alias -l crand { var %v, %i 1 | while (%i <= $3) { %v = $+(%v,$rand($1,$2)) | inc %i } | return %v }
alias -l hash_storage_time { return 900 }
#CaptchaChannelSecurity end