#####################################################################
#   Название: No Spam Chan v1.1
#   Автор: Epic (epicnet@mail.ru, http://epicnet.ru)
#   Описание: Скрипт осуществляет мониторинг общения на канале с целью поиска в строках символа "#" для выявления рекламы других каналов.
#####################################################################

alias -l nospamchan {
  ;# Вы можете включать или отключать опции изменяя значение на <yes> или <no>
  ;---------------------
  ;# Type 1 = nick!ident@host
  ;# Type 2 = nick!*@host
  ;# Type 3 = *!ident@host
  ;# Type 4 = nick!*@*
  ;# Type 5 = *!ident@*
  ;# Type 6 = *!*@host
  ;# Type 7 = *!*@subnet*
  ;---------------------
  .hadd -m nospamchan type-ban 6
  .hadd -m nospamchan kick yes
  .hadd -m nospamchan ban yes
  .hadd -m nospamchan kick-text Реклама каналов запрещена!
}
---------------------------------------------------------------------
on *:TEXT:*#*:#: nospamchan_check $nick $chan $strip($1-)
on *:ACTION:*#*:#: nospamchan_check $nick $chan $strip($1-)
alias -l nospamchan_check {
  if ($1 == $server) halt | nospamchan
  .hadd -m nospamchan nick $1
  .hadd -m nospamchan chan $2
  .hadd -m nospamchan search $wildtok($3-,*#*,1,32)
  .who $hget(nospamchan,search)
}
raw 352:*: if ($2 == $hget(nospamchan,search)) { .hadd -m nospamchan found $2 | halt } | haltdef
raw 315:*:{
  if ($2 == $hget(nospamchan,found) && $hget(nospamchan,nick)) {
    ;---------------------
    if ($hget(nospamchan,ban) == yes) {
      if ($hget(nospamchan,type-ban) == 1) .mode $hget(nospamchan,chan) +b $address($hget(nospamchan,nick),5)
      if ($hget(nospamchan,type-ban) == 2) .mode $hget(nospamchan,chan) +b $address($hget(nospamchan,nick),7)
      if ($hget(nospamchan,type-ban) == 3) .mode $hget(nospamchan,chan) +b $address($hget(nospamchan,nick),0)
      if ($hget(nospamchan,type-ban) == 4) .mode $hget(nospamchan,chan) +b $+($hget(nospamchan,nick),!*@*)
      if ($hget(nospamchan,type-ban) == 5) .mode $hget(nospamchan,chan) +b $+($gettok($address($hget(nospamchan,nick),1),1,64),@*)
      if ($hget(nospamchan,type-ban) == 6) .mode $hget(nospamchan,chan) +b $address($hget(nospamchan,nick),2)
      if ($hget(nospamchan,type-ban) == 7) .mode $hget(nospamchan,chan) +b $+(*!*@,$gettok($gettok($address($hget(nospamchan,nick),5),2,64),1-2,46),.*)
    }
    ;---------------------
    if ($hget(nospamchan,kick) == yes) .kick $hget(nospamchan,chan) $hget(nospamchan,nick) $hget(nospamchan,kick-text)
    if ($hget(nospamchan,nick)) .hdel -sw nospamchan nick
    if ($hget(nospamchan,chan)) .hdel -sw nospamchan chan
    if ($hget(nospamchan,search)) .hdel -sw nospamchan search
    if ($hget(nospamchan,found)) .hdel -sw nospamchan found
    halt
  }
  haltdef
}