Название: Find Nick Channels v1.1
Скрипт: FindNickChannels.mrc
Программа: mIRC
Автор: Epic
Описание: Скрипт выполняет поиск указанного ника во всех каналах сети. Все настройки производятся в диалоговом окне панели управления, которое вызывается через всплывающее меню окон при нажатии правой кнопки мыши.

Требования: Обязательно настройте все поля в меню панели управления. Каждый сервер имеет свою защиту от флуда посылаемых команд, поэтому настройте работу таймера входа и выхода на каналы по максимуму. Постарайтесь не ставить слишком маленькое значения в миллисекундах, иначе сервер может расценить это как флуд.

Скриншоты:
[indent=0.8,0.5] https://i.ibb.co/nCG3XhZ/Search-Nick-v1-1.jpg

Установка:

  • Откройте редактор скриптов вашего клиента при помощи комбинации клавиш "ALT+R".

  • Далее через верхнее меню "File/New" откройте новый файл и разместите там код.

  • Далее через верхнее меню "File/Save As..." сохраните код как скрипт под названием "FindNickChannels.mrc".

  • Если у вас уже установлена предыдущая версия этого скрипта, то замените его новым кодом. Не оставляйте предыдущие версии скриптов во избежании конфликтов.

Скачать: 💾 FindNickChannels_v1.1.rar

Код:
#####################################################################
#   Название: Find Nick Channels v1.1
#   Автор: Epic (epicnet@mail.ru, http://epicnet.ru)
#   Описание: Скрипт выполняет поиск указанного ника во всех каналах сети.
#   Управление: Все настройки производятся в диалоговом окне панели управления, которое вызывается через всплывающее меню окон при нажатии правой кнопки мыши.
#####################################################################

menu status,channel {
  -
  ¤ Find Nick Channels: searchnick
}
alias searchnick {
  searchnick_delete | searchnick_data | searchnick_dialog
}
alias searchnick_data {
  if (!%sn_pfile) %sn_pfile = chanlist.txt
  if (!%sn_tjoin) %sn_tjoin = 100
  if (!%sn_tpart) %sn_tpart = 3000
  if (!%sn_talias) %sn_talias = 3000
}
alias searchnick_dialog { dialog -mpr searchnick searchnick }
dialog searchnick {
  title "Find Nick"
  size -1 -1 210 265
  text "Ник для поиска:", 1, 15 10 220 12
  edit %sn_nick, 2, 15 25 180 20, rich autohs
  text "Файл для сохранения списка:", 3, 15 50 220 12
  edit %sn_pfile, 4, 15 65 180 20, rich autohs
  text "Время в м.сек. перед входом:", 5, 15 90 220 12
  edit %sn_tjoin, 6, 15 105 180 20, rich autohs
  text "Время в м.сек. перед выходом:", 7, 15 130 220 12
  edit %sn_tpart, 8, 15 145 180 20, rich autohs
  text "Время в м.сек. для цикла:", 9, 15 170 220 12
  edit %sn_talias, 10, 15 185 180 20, rich autohs
  button "Поиск", 11, 30 220 150 25, flat
}
on *:dialog:searchnick:sclick:11:{
  %sn_nick = $did($dname,2).text
  %sn_pfile = $did($dname,4).text
  %sn_tjoin = $did($dname,6).text
  %sn_tpart = $did($dname,8).text
  %sn_talias = $did($dname,10).text
  searchnick_start %sn_nick
}
alias searchnick_start {
  if ($len($1) > 0) { %sn_start = 1 | /list -n }
  else { /echo -a Ошибка: - Введите в первое поле ник для поиска. }
}
raw 322:*: if (%sn_start == 1) { .write -i %sn_pfile $2-3 }
raw 323:*: if (%sn_start == 1) { searchnick_join }
raw 366:*: if (%sn_start == 1) { %sn_craw = $2 }
raw 353:*:{
  if (%sn_start == 1 && %sn_craw != $3) {
    var %sn_nraw $remove($4-,~,&,@,%,+)
    if (%sn_nick isin %sn_nraw && $3 !isin %sn_r) { %sn_r = %sn_r $3 }
  }
}
alias searchnick_join {
  if (%sn_ns >= $lines(%sn_pfile)) { searchnick_finish }
  inc %sn_ns
  var %sn_str1 $gettok($read(%sn_pfile,%sn_ns),1,32)
  var %sn_str2 $gettok($read(%sn_pfile,%sn_ns),2,32)
  if (%sn_str2 > 0) {
    .timerSNJ $+ %sn_str1 -m 1 %sn_tjoin /join -n %sn_str1
    .timerSNP $+ %sn_str1 -m 1 %sn_tpart /part %sn_str1
  }
  .timerSNA -m 1 %sn_talias searchnick_join
}
alias searchnick_finish {
  if (%sn_r) { /echo -a >>> Ник: %sn_nick >>> найден на: %sn_r }
  else { /echo -a >>> Ник: %sn_nick >>> нигде не найден. }
  searchnick_delete | halt
}
alias searchnick_delete {
  if (%sn_pfile) .remove %sn_pfile | unset %sn_start %sn_ns %sn_r %sn_craw
}

P.S. Если у вас возникли вопросы, вы столкнулись с трудностями по установке скрипта, или вы обнаружили ошибки, а может быть у вас появились новые идеи по модификации данного скрипта, то обязательно напишите здесь об этом.

Подпись автора

[html]<style>img {vertical-align:middle;}.hnet{color:#FFFFFF;}.hstar{color:#DE0000;}.htext{font-family:Verdana;font-size:13px;color:#6E1E00;}.heading{font-family:Verdana;font-size:13px;font-weight:bold;background-color:#4898CD;}.stitle{font-family:Verdana;font-size:12px;}.dot{color:#808000;}.desc{color:#B5B5B5;}a .curl{font-family:Verdana;font-size:12px;color:#3A92CD;}</style><table><tr><td width="20px" height="20px"><img src="http://forumstatic.ru/files/000d/c9/8c/34681.jpg"></td><td><a href="https://forum.epicnet.ru/viewtopic.php?id=234"><span class="heading"> <span class="hstar">★</span> <span class="hnet">EpicNet.Ru</span> <span class="hstar">★</span> </span><span class="htext"> - Российский IRC Чат © 2009</span></a></td></tr><tr><td></td><td><div class="stitle"><span class="dot">•</span> <span class="desc">Онлайн:</span> <a href="http://chat.epicnet.ru"><span class="curl">http://chat.epicnet.ru</span></a><br><span class="dot">•</span> <span class="desc">Сервер:</span> irc.epicnet.ru <span class="desc">Порты:</span> 6667, 6668 (ssl) <span class="desc">Кодировка:</span> UTF-8<br><span class="dot">•</span> <span class="desc">Сайт:</span> <a href="http://epicnet.ru"><span class="curl">http://epicnet.ru</span></a> <span class="dot">•</span> <span class="desc">ВКонтакте:</span> <a href="https://vk.com/irc_epicnet"><span class="curl">https://vk.com/irc_epicnet</span></a><br><div></td></tr></table>[/html]