Название: Decoder Hex IP v1.1
Скрипт: DecoderHexIP.mrc
Программа: mIRC
Автор: Epic
Описание: Помогает расшифровать IР-адрес закодированный в шестнадцатеричном формате, который может находиться в иденте пользователя. Скрипт срабатывает автоматически, как только пользователь присоединяется к каналу. Каждый раз, когда ваш бот будет присоединяться к новому каналу, он будет выполнять команду "/who #channel" для получения данных пользователей, чтобы корректно работал идентификатор $address. Вы можете узнать IР-адрес по ID, даже когда пользователь уже отключился от сети. Вы можете выбрать способ отправки сообщения скриптом между "/msg", "/notice", "/echo" или отправить его на указанный сервисный канал при помощи "/msg #Services". Просто удалите знак ";" перед соответствующей строкой внизу кода.

Требования: Скрипт будет работать правильно, только если идентификатор пользователя закодирован в 8-символьном шестнадцатеричном формате. Например это может быть закодировано таким вебгейтом как "Mibbit" или подобным этому сервису для онлайн чата. Но имейте в виду, что идентификатор пользователя может быть просто случайным набором символов. В таком случае этот скрипт ничего не сможет расшифровать или будет давать неверный IP адрес. Поэтому вы должны указать в переменной "%di_target" только те маски (присутствующие в хосте пользователя) с названиями сервиса, которые реально шифруют IP адрес в виде идента пользователя, чтобы скрипт мог вернуть вам правильный результат.

Настройка: Вы можете в переменной "%di_target" создать свой список из слов разделённых пробелами, на которые будет срабатывать скрипт, если одно из них будет присутствовать в хосте пользователя.

Управление: Синтаксис команды: "!hex ‹nick|ident›".

Скриншоты:
[indent=0.8,0.5] https://i.ibb.co/9swH8d2/DecoderIP.jpg

Установка:

  • Откройте редактор скриптов вашего клиента при помощи комбинации клавиш "ALT+R".

  • Далее через верхнее меню "File/New" откройте новый файл и разместите там код.

  • Далее через верхнее меню "File/Save As..." сохраните код как скрипт под названием "DecoderHexIP.mrc".

  • Если у вас уже установлена предыдущая версия этого скрипта, то замените его новым кодом. Не оставляйте предыдущие версии скриптов во избежании конфликтов.

Скачать: 💾 DecoderHexIP_v1.1.rar

Код:
#####################################################################
#   Название: Decoder Hex IP v1.1
#   Автор: Epic (epicnet@mail.ru, http://epicnet.ru)
#   Описание: Расшифровывает IP-адрес закодированный в шестнадцатеричном формате, который может находиться в идентификаторе пользователя.
#   Управление: !hex <nick|ident>.
#####################################################################

on *:JOIN:#: if ($nick == $me) { %di_who = true | .who $chan } | else dec_ip $nick $chan $me join
on *:TEXT:!hex*:#: if ($2) { dec_ip $2 $chan $nick text } | else .notice $nick Синтаксис: !hex <nick/ident>
raw 352:*: if (%di_who == true) haltdef
raw 315:*: if (%di_who == true) { haltdef | unset %di_who }
alias -l dec_ip {
  ;------------------------------
  %di_target = webgate. .mibbit .virtual
  ;------------------------------
  var %di_value $strip($1)
  if ($comchan(%di_value,0) > 0) {
    var %di_nick %di_value | var %di_host $gettok($address(%di_nick,2),2,64)
    var %di_ident $remove($gettok($address(%di_nick,1),1,64),*!*)
    if ($di_check(%di_nick,%di_host) == true && $len(%di_ident) == 8) {
      var %di_ip $longip($base(%di_ident,16,10))
      var %di_return DecoderHexIP: $+(06,%di_nick,) -> $+(%di_ident,@,04,%di_ip,) -> $+($chr(40),%di_host,$chr(41))
    }
  }
  if ($comchan(%di_value,0) == 0 && $len(%di_value) == 8) {
    var %di_ip $longip($base(%di_value,16,10))
    var %di_return DecoderHexIP: $+(06,%di_value,) -> $+(04,%di_ip,)
  }
  if (%di_return) di_message $1 $2 $3 %di_return
}
alias -l di_check {
  var %di_q 1 | while (%di_q <= $numtok(%di_target,32)) {  
    if ($gettok(%di_target,%di_q,32) isin $2) return true | inc %di_q
  }
  return false
}
alias -l di_message {
  ;/echo $2 $4-
  ;/notice $3 $2 $4-
  ;/msg #Services $2 $4-
  /msg $2 $4-
}

P.S. Если у вас возникли вопросы, вы столкнулись с трудностями по установке скрипта, или вы обнаружили ошибки, а может быть у вас появились новые идеи по модификации данного скрипта, то обязательно напишите здесь об этом.

Подпись автора

[html]<style>img {vertical-align:middle;}.hnet{color:#FFFFFF;}.hstar{color:#DE0000;}.htext{font-family:Verdana;font-size:13px;color:#6E1E00;}.heading{font-family:Verdana;font-size:13px;font-weight:bold;background-color:#4897E7;}.stitle{font-family:Verdana;font-size:12px;}.dot{color:#808000;}.desc{color:#ADADAD;}a .curl{font-family:Verdana;font-size:13px;color:#3A92CD;}</style><table><tr><td width="20px" height="20px"><img src="https://forumstatic.ru/files/000d/c9/8c/34681.jpg"></td><td><a href="https://forum.epicnet.ru/viewtopic.php?id=234"><span class="heading"> <span class="hstar">★</span> <span class="hnet">EpicNet.Ru</span> <span class="hstar">★</span> </span><span class="htext"> - IRC Чат © 2008</span></a></td></tr><tr><td></td><td><div class="stitle"><span class="dot">•</span> <span class="desc">Вход через вебгейт:</span> <a href="http://irc.epicnet.ru"><span class="curl">http://irc.epicnet.ru</span></a><br><span class="dot">•</span> <span class="desc">Сервер:</span> irc.epicnet.ru <span class="desc">Порты:</span> 6667, 6668 (ssl)<br><div></td></tr></table>[/html]