#####################################################################
#   Название: Auto Limit Users v1.1
#   Автор: Epic (epicnet@mail.ru, http://epicnet.ru, irc.epicnet.ru:6667 #Code)
#   Описание: Автоматически устанавливает режим лимита (+l) для максимально допустимого числа пользователей на канале.
#####################################################################

alias -l alu_set {
  %alu_max_join = 4
  %alu_max_part = 4
  %alu_max_kick = 4
  %alu_max_quit = 4
  ;----------------
  %alu_timer_join = 15
  %alu_timer_part = 3
  %alu_timer_kick = 3
  %alu_timer_quit = 3
  ;----------------
  %alu_limit_join = 5
  %alu_limit_part = 5
  %alu_limit_kick = 5
  %alu_limit_quit = 5
  ;----------------
  %alu_networks = EpicNet.Ru,DaVang
}
---------------------------------------------------------------------
on !*:JOIN:#: alu
on *:PART:#: alu
on *:KICK:#: alu
on *:QUIT: alu
alias -l alu {
  alu_set | if (!$istok(%alu_networks,$network,44)) { halt }
  if ($event == join) {
    .hinc -m alu_join $chan 1 | if ($hget(alu_join,$chan) >= %alu_max_join) {
      if ($me isop $chan) .timerALU_JOIN_ $+ $chan 1 %alu_timer_join mode $chan +l $calc($nick($chan,0) + %alu_limit_join) | .hdel -sw alu_join $chan
    }
  }
  if ($event == part) {
    .hinc -m alu_part $chan 1 | if ($hget(alu_part,$chan) >= %alu_max_part) {
      if ($me isop $chan) .timerALU_PART_ $+ $chan 1 %alu_timer_part mode $chan +l $calc($nick($chan,0) + %alu_limit_part -1) | .hdel -sw alu_part $chan
    }
  }
  if ($event == kick) {
    .hinc -m alu_kick $chan 1 | if ($hget(alu_kick,$chan) >= %alu_max_kick) {
      if ($me isop $chan) .timerALU_KICK_ $+ $chan 1 %alu_timer_kick mode $chan +l $calc($nick($chan,0) + %alu_limit_kick -1) | .hdel -sw alu_kick $chan
    }
  }
  if ($event == quit) {
    var %i 1 | while (%i <= $comchan($nick,0)) {
      var %chan $comchan($nick,%i) | .hinc -m alu_quit %chan 1 | if ($hget(alu_quit,%chan) >= %alu_max_quit) {
        if ($me isop %chan) .timerALU_QUIT_ $+ %chan 1 %alu_timer_quit mode %chan +l $calc($nick(%chan,0) + %alu_limit_quit -1) | .hdel -sw alu_quit %chan
      } | inc %i
    }
  }
}
---------------------------------------------------------------------

#####################################################################
#   Название: Auto Limit Users v1.2
#   Автор: Epic (http://epicnet.ru, irc.epicnet.ru:6667 #Code)
#   Описание: Автоматически устанавливает режим лимита (+l) для максимально допустимого числа пользователей на канале.
#####################################################################

menu menubar,status,channel {
  Auto Limit Users: alu_dialog
}
alias -l alu_dialog { alu_default_set | if ($dialog(alu)) .dialog -x alu | .dialog -m alu alu }
dialog alu {
  title "Auto Limit Users"
  size -1 -1 300 272
  option pixels
  icon $mircexe,22
  ;---------------
  text "Only in this networks (separated by commas):", 1, 30 27 240 15
  edit %alu_networks, 2, 30 44 240 20, autohs
  box "Numeric parameters:", 3, 30 81 240 140
  text "Join Timer:", 4, 43 110 60 15, right
  edit %alu_timer_join, 5, 107 107 30 20, autohs, limit 3
  text "Part Timer:", 6, 43 135 60 15, right
  edit %alu_timer_part, 7, 107 132 30 20, autohs, limit 3
  text "Kick Timer:", 8, 43 160 60 15, right
  edit %alu_timer_kick, 9, 107 157 30 20, autohs, limit 3
  text "Quit Timer:", 10, 43 185 60 15, right
  edit %alu_timer_quit, 11, 107 182 30 20, autohs, limit 3
  text "Max Events:", 12, 155 110 60 15, right
  edit %alu_max_events, 13, 219 107 30 20, autohs, limit 3
  text "Plus Limit:", 14, 155 135 60 15, right
  edit %alu_plus_limit, 15, 219 132 30 20, autohs, limit 3
  button "Default", 99, 30 236 75 23, center flat
  button "OK", 100, 195 236 75 23, center flat default ok
}
on *:DIALOG:alu:edit:2: if ($len($did($did).text) > 0) %alu_networks = $did($did).text | else unset %alu_networks
on *:DIALOG:alu:edit:5: %alu_timer_join = $did($did).text
on *:DIALOG:alu:edit:7: %alu_timer_part = $did($did).text
on *:DIALOG:alu:edit:9: %alu_timer_kick = $did($did).text
on *:DIALOG:alu:edit:11: %alu_timer_quit = $did($did).text
on *:DIALOG:alu:edit:13: %alu_max_events = $did($did).text
on *:DIALOG:alu:edit:15: %alu_plus_limit = $did($did).text
on *:DIALOG:alu:sclick:99: unset %alu_* | alu_dialog
---------------------------------------------------------------------
alias -l alu_default_set {
  if (!%alu_timer_join) || (%alu_timer_join == $null) { %alu_timer_join = 10 }
  if (!%alu_timer_part) || (%alu_timer_part == $null) { %alu_timer_part = 5 }
  if (!%alu_timer_kick) || (%alu_timer_kick == $null) { %alu_timer_kick = 5 }
  if (!%alu_timer_quit) || (%alu_timer_quit == $null) { %alu_timer_quit = 5 }
  if (!%alu_max_events) || (%alu_max_events == $null) { %alu_max_events = 3 }
  if (!%alu_plus_limit) || (%alu_plus_limit == $null) { %alu_plus_limit = 5 }
}
---------------------------------------------------------------------
on !*:JOIN:#: alu
on *:PART:#: alu
on *:KICK:#: alu
on *:QUIT: alu
alias -l alu {
  alu_default_set | if (%alu_networks && !$istok(%alu_networks,$network,44)) { halt }
  if ($event == join) {
    .hinc -m $+(alu_,$chan) join 1 | if ($hget($+(alu_,$chan),join) >= %alu_max_events) {
      if ($me isop $chan) .timerALU_ $+ $chan 1 %alu_timer_join mode $chan +l $calc($nick($chan,0) + %alu_plus_limit) | .hdel -sw $+(alu_,$chan) *
    }
  }
  if ($event == part) {
    .hinc -m $+(alu_,$chan) part 1 | if ($hget($+(alu_,$chan),part) >= %alu_max_events) {
      if ($me isop $chan) .timerALU_ $+ $chan 1 %alu_timer_part mode $chan +l $calc($nick($chan,0) + %alu_plus_limit -1) | .hdel -sw $+(alu_,$chan) *
    }
  }
  if ($event == kick) {
    .hinc -m $+(alu_,$chan) kick 1 | if ($hget($+(alu_,$chan),kick) >= %alu_max_events) {
      if ($me isop $chan) .timerALU_ $+ $chan 1 %alu_timer_kick mode $chan +l $calc($nick($chan,0) + %alu_plus_limit -1) | .hdel -sw $+(alu_,$chan) *
    }
  }
  if ($event == quit) {
    var %i 1 | while (%i <= $comchan($nick,0)) {
      var %chan $comchan($nick,%i) | .hinc -m $+(alu_,%chan) quit 1 | if ($hget($+(alu_,%chan),quit) >= %alu_max_events) {
        if ($me isop %chan) .timerALU_ $+ %chan 1 %alu_timer_quit mode %chan +l $calc($nick(%chan,0) + %alu_plus_limit -1) | .hdel -sw $+(alu_,%chan) *
      } | inc %i
    }
  }
}
---------------------------------------------------------------------