Я создал небольшой скрипт для Бота, который должен делать то, что вы просите.

Синтаксис команды:  !ban <host/ip>

После того как вы напишите команду на канале, Бот установит "Ban" на указанный хост, а также выполнит "Kick" для всех присутствующих ников пользователей, чей "Host/IP" совпадает с указанным адресом в команде.

Для ограничения прав доступа вы должны заполнить файл "admins.txt", указав в столбик все ники пользователей, которым разрешено использовать эту команду.
Примечание: Все файлы, с которыми работает скрипт должны находиться в той же папке, где находится сам скрипт.

[indent=0.8,0.5]
Итак, вы можете попробовать использовать этот код скрипта:

on @*:TEXT:!ban*:#:{
  if (!$read($file_admins,ntw,$nick)) { return }
  if (!$2) { .notice $nick Syntax:12 !ban <host/ip> | return }
  mode $chan +b $+(*!*@,$2) | .enable #kicknicks | who $chan $+($chr(37),cn) $2
}
alias -l file_admins { return $scriptdir $+ admins.txt }
alias -l kick_reason { return You have been banned! }

#kicknicks off
raw 354:*: kick $2 $3 $kick_reason | haltdef
raw 315:*: .disable #kicknicks | haltdef
#kicknicks end

Обязательно оставьте свои отзывы и комментарии по результатам тестирования данного скрипта.

Подпись автора

[html]<style>img {vertical-align:middle;}.hnet{color:#FFFFFF;}.hstar{color:#DE0000;}.htext{font-family:Verdana;font-size:13px;color:#6E1E00;}.heading{font-family:Verdana;font-size:13px;font-weight:bold;background-color:#4897E7;}.stitle{font-family:Verdana;font-size:12px;}.dot{color:#808000;}.desc{color:#ADADAD;}a .curl{font-family:Verdana;font-size:13px;color:#3A92CD;}</style><table><tr><td width="20px" height="20px"><img src="https://forumstatic.ru/files/000d/c9/8c/34681.jpg"></td><td><a href="https://forum.epicnet.ru/viewtopic.php?id=234"><span class="heading"> <span class="hstar">★</span> <span class="hnet">EpicNet.Ru</span> <span class="hstar">★</span> </span><span class="htext"> - IRC Чат © 2008</span></a></td></tr><tr><td></td><td><div class="stitle"><span class="dot">•</span> <span class="desc">Вход через вебгейт:</span> <a href="http://irc.epicnet.ru"><span class="curl">http://irc.epicnet.ru</span></a><br><span class="dot">•</span> <span class="desc">Сервер:</span> irc.epicnet.ru <span class="desc">Порты:</span> 6667, 6668 (ssl)<br><div></td></tr></table>[/html]

Ок. Я изменил ваш код с учётом описанной вами просьбы, чтобы он делал то, что вы просите.

К тому же, как я понимаю скрипт должен удалять по команде только пользователей из специального списка с IP/Хост адресами, а не самих администраторов, которые имеют доступ управления ботом, иначе в этом нет смысла, т.к. в этом случае любой администратор бота сможет удалить другого администратора бота из общего списка, после чего выполнится "Ban+Kick". Поэтому было бы логичнее переименовать команду "adminbotdel" на "userbotdel". Если я неправильно понимаю идею и логику вашего скрипта, то объясните подробнее.

Итак, вы можете попробовать использовать этот код скрипта:

on @*:TEXT:*:#:{
  tokenize 32 $strip($1-)
  if ($com_prefixes($1,adminbotdel,~.!)) {
    var %host $ial($nick).host, %file_botadmins $read($file_botadmins,ntw,%host)
    if (!%file_botadmins) { .notice $nick Access denied. Only Bot Admin can use this command! | return }
    if (!$2) { .notice $nick Syntax: 12~adminbotdel/.adminbotdel/!adminbotdel <ip/host>. Example: 12~adminbotdel 10.20.30.40 or 12~adminbotdel Nick.users.undernet.org | return }
    var %file_botusers $read($file_botusers,ntw,$2)), %line $readn
    if (!%file_botusers) { .notice $nick Sorry, ip/host $+(",,$2,,") does NOT exists on the list of $qt($file_botusers) database. | return }
    else { 
      write -dl $+ %line $qt($file_botusers) | ban $+(-u,$ban_timer) $chan $2 2 | .enable #kicknicks | who $chan $+($chr(37),cn) $2
      .notice $nick Deleted $+(",04,$2,,") from $+(04,%line,) line on the list of $qt($file_botusers) successfull.
    }
  }
}
alias -l file_botadmins { return $scriptdir $+ botadmins.txt }
alias -l file_botusers { return $scriptdir $+ botusers.txt }
alias -l ban_timer { return $rand(3600,10800) }
alias -l kick_reason { return 04You are not permitted to join $1 anymore! }
alias -l com_prefixes { if ($1 == $2) || ($2 isin $1 && $left($1,1) isin $3) { return $true } }

#kicknicks off
raw 354:*: kick $2 $3 $kick_reason($2) | haltdef
raw 315:*: .disable #kicknicks | haltdef
#kicknicks end

Описание настроек:

• Алиас "file_botadmins" возвращает путь к файлу "botadmins.txt", который должен содержать список IP/Хостов пользователей, перечисленных в столбик, которые имеют право доступа для использования команды "adminbotdel".

• Алиас "file_botusers" возвращает путь к файлу "botusers.txt", который может содержать список IP/Хостов пользователей, перечисленных в столбик, которые имеют некие права на канале, и о которых должен знать Бот для обеспечения контроля безопасности. Например Бот сможет устанавливать для всех пользователей этого списка право голоса "Voice" (+v) на канале, когда на нём установлен режим модерации (+m). Вы можете реализовать это самостоятельно и дополнить весь необходимый вам функционал на своё усмотрение.

• Алиас "ban_timer" возвращает случайное (рандомное) числовое значение в секундах для установки времени таймера, по истечению которого Бан должен быть снят. Вы можете изменить это значение на постоянное целое число, которое измеряется в секундах.

• Алиас "kick_reason" возвращает текстовое сообщение для установки причины Кика пользователя на канале.

• Алиас "com_prefixes" делает проверку, какие префиксы - из передаваемых в параметрах символов "~.!" могут использоваться вместе с командой "adminbotdel" и возвращает "$true", если используется один из этих символов или если ничего не используется в качестве префикса команды.

Примечание: Все файлы, с которыми работает скрипт должны находиться в той же папке, где находится сам скрипт.

Подпись автора

[html]<style>img {vertical-align:middle;}.hnet{color:#FFFFFF;}.hstar{color:#DE0000;}.htext{font-family:Verdana;font-size:13px;color:#6E1E00;}.heading{font-family:Verdana;font-size:13px;font-weight:bold;background-color:#4897E7;}.stitle{font-family:Verdana;font-size:12px;}.dot{color:#808000;}.desc{color:#ADADAD;}a .curl{font-family:Verdana;font-size:13px;color:#3A92CD;}</style><table><tr><td width="20px" height="20px"><img src="https://forumstatic.ru/files/000d/c9/8c/34681.jpg"></td><td><a href="https://forum.epicnet.ru/viewtopic.php?id=234"><span class="heading"> <span class="hstar">★</span> <span class="hnet">EpicNet.Ru</span> <span class="hstar">★</span> </span><span class="htext"> - IRC Чат © 2008</span></a></td></tr><tr><td></td><td><div class="stitle"><span class="dot">•</span> <span class="desc">Вход через вебгейт:</span> <a href="http://irc.epicnet.ru"><span class="curl">http://irc.epicnet.ru</span></a><br><span class="dot">•</span> <span class="desc">Сервер:</span> irc.epicnet.ru <span class="desc">Порты:</span> 6667, 6668 (ssl)<br><div></td></tr></table>[/html]